ekkehard
Fri Feb 23 13:31:13 CST 2007
Drn wrote:
> Greetings,
>
> Example Code:
> -----------------------------------------------
> testString = "<div>Hi there, what's new?</div>"
> objRegEx.Pattern = "<div>(.*)</div>"
> objRegEx.Global = true
> objRegEx.IgnoreCase = true
>
> str = objRegEx.Replace(testString, "The results are: $1")
> ----------------------------------------------
>
> Unless I have something wrong, it appears that $1 is only "returned"
> by VBScript. In other words, I can't put it into a variable or call
> functions on it. I need to put the value of $1 into a javascript
> variable and need to escape all of the single quotes, backslashes,
> newlines, etc. Is there any way I can change the last line to:
>
> str = objRegEx.Replace(testString, "The results are:" & replace("$1",
> "\", "\\'")
>
> and also have it work?
>
> Help appreciated!
> DRN
>
Some code
Dim aTests : aTests = Array( _
"<div>Hi there, what's new?</div>" _
, "<div>Hi there, what's new?</div>REs are greedy<div>by default.</div>" _
, "<div>Hi there, what's new? And CRLF" + vbCrLf + " is nasty too</div>" _
)
Dim aPatts : aPatts = Array( _
"<div>(.*)</div>" _
, "<div>(.*?)</div>" _
, "<div>([\s\S]*?)</div>" _
)
Dim sTest, sPatt
For Each sTest In aTests
For Each sPatt In aPatts
WScript.Echo Replace( Embrace( Array( sTest, sPatt ), "|" ), vbCrLf, "\r\n" )
Dim oRE : Set oRE = New RegExp
oRE.Pattern = sPatt
Dim oMTS : Set oMTS = oRE.Execute( sTest )
If 1 = oMTS.Count Then
WScript.Echo Replace( " |" + oMTS( 0 ).SubMatches( 0 ) + "|", vbCrLf,
"\r\n" )
Else
WScript.Echo "Not: 1 = oMTS.Count"
End If
WScript.Echo "-----------------"
Next
Next
Function Embrace( aItems, sDelim )
Embrace = sDelim + Join( aItems, sDelim ) + sDelim
End Function
and output:
=== greedyRE: Regexps are greedy by default ===================================
|<div>Hi there, what's new?</div>|<div>(.*)</div>|
|Hi there, what's new?|
-----------------
|<div>Hi there, what's new?</div>|<div>(.*?)</div>|
|Hi there, what's new?|
-----------------
|<div>Hi there, what's new?</div>|<div>([\s\S]*?)</div>|
|Hi there, what's new?|
-----------------
|<div>Hi there, what's new?</div>REs are greedy<div>by default.</div>|<div>(.*)</div>|
|Hi there, what's new?</div>REs are greedy<div>by default.|
-----------------
|<div>Hi there, what's new?</div>REs are greedy<div>by default.</div>|<div>(.*?)</div>|
|Hi there, what's new?|
-----------------
|<div>Hi there, what's new?</div>REs are greedy<div>by default.</div>|<div>([\s\S]*?)</div>|
|Hi there, what's new?|
-----------------
|<div>Hi there, what's new? And CRLF\r\n is nasty too</div>|<div>(.*)</div>|
Not: 1 = oMTS.Count
-----------------
|<div>Hi there, what's new? And CRLF\r\n is nasty too</div>|<div>(.*?)</div>|
Not: 1 = oMTS.Count
-----------------
|<div>Hi there, what's new? And CRLF\r\n is nasty too</div>|<div>([\s\S]*?)</div>|
|Hi there, what's new? And CRLF\r\n is nasty too|
-----------------
=== greedyRE: 0 done (00:00:00) ===============================================
(sorry about the word wrap) to show you:
(1) your pattern is dangerous because .* is greedy (tries to match
the longest possible sequence
(2) .*? is non-greedy (matches the shortest possible sequence)
(3) . means: everything except newline; so to match across lines you need to
use the tricky [\s\S] (all spaces and all non spaces - i.e. really
everything)
(4) you can use the MatchCollection object to get the Matches (here just
one) and a Match to get at it's SubMatches (= the material collected
by the () in the pattern; just be aware of $1, $2, .. but .SubMatches(0),
.SubMatches(1), ..)
I don't understand the necessity of mixing languages and all the things you
want to do to the resulting string, but I'd consider carefully, whether using
the DOM to access/manipulate the elements would be easier/safer.