Torgeir
Sat Jul 23 15:18:30 CDT 2005
jaime wrote:
> script to obtain information of SO, name of the PC, memory,
> verision SO, version IE, etc...
Hi,
Hard and Soft Asset Management with VBScript
http://pubs.logicalexpressions.com/Pub0009/LPMArticle.asp?ID=339
Here is another one:
Using WMI for Inventory Management
http://www.serverwatch.com/tutorials/article.php/1475601
"A WSH script using VBScript is explained. The script uses
WMI to query a computer for some predetermined information.
The acquired information is written to a database using ADO."
The database used in the example above is Microsoft Access.
Here is an third example:
For inventory to a csv file using WMI from vbscript (WMI comes default
with WinME, Win2k and WinXP), in the quickFIND field, search for:
poor mans sms
at Win32 Scripting [Clarence Washington]
http://cwashington.netreach.net/depo/default.asp?topic=repository&scripttype=vbscript
My own InstalledApplications procedure:
http://groups.google.com/groups?selm=40280AFD.7BA89056%40hydro.com
remote version:
http://groups.google.com/groups?selm=ua4afeAOEHA.808%40tk2msftngp13.phx.gbl
To obtain the IE version, take a look at the functions
GetIEMajorVersion and GetIEExactVersion below.
'--------------------8<----------------------
Option Explicit
WScript.Echo GetIEMajorVersion
WScript.Echo GetIEExactVersion
Function GetIEMajorVersion()
' Will return the major version number of Internet Explorer
Dim oShell, aIEVersion, sIEBuild, sIEFullVersion
Set oShell = CreateObject("WScript.Shell")
sIEBuild = "" : sIEFullVersion = "" ' init values
On Error Resume Next
sIEBuild = oShell.RegRead _
("HKLM\Software\Microsoft\Internet Explorer\Build")
sIEFullVersion = oShell.RegRead _
("HKLM\Software\Microsoft\Internet Explorer\Version")
On Error Goto 0
If Not sIEFullVersion = "" Then
aIEVersion = Split(sIEFullVersion,".", -1, 1)
End If
If sIEFullVersion = "" AND sIEBuild = "" Then
GetIEMajorVersion = 0
ElseIf sIEFullVersion = "" And Not sIEBuild = "" Then
'IE3.0 sets only the Build value and not the Version
GetIEMajorVersion = 3.0
ElseIf aIEVersion(0) = "4" Then
GetIEMajorVersion = 4.0
ElseIf aIEVersion(0) = "5" And aIEVersion(1)= "0" Then
GetIEMajorVersion = 5.0
ElseIf aIEVersion(0) = "5" And aIEVersion(1)= "50" Then
GetIEMajorVersion = 5.5
ElseIf aIEVersion(0) = "6" And aIEVersion(1)= "0" Then
GetIEMajorVersion = 6.0
Else
GetIEMajorVersion = CDbl(aIEVersion(0) & "." & aIEVersion(1))
End If
End Function
Function GetIEExactVersion
' Will return the exact version inclusive service pack level
' of Internet Explorer 5.01 and up.
'
' IE version testing based on registry values listed in
'
' How to Determine Which Version of Internet Explorer Is Installed
'
http://support.microsoft.com/?kbid=164539
Dim oShell, sUnknownText, sRegPath, sIEVer, aIEVer
Dim iIEVersion, iIEBuildVersion
Set oShell = CreateObject("WScript.Shell")
sUnknownText = "Unknown IE"
sRegPath = "HKLM\SOFTWARE\Microsoft\Internet Explorer\Version"
sIEVer = "" ' init value
On Error Resume Next
sIEVer = oShell.RegRead(sRegPath)
If Err.Number <> 0 Or sIEVer = "" Then
' IE version is 3.0 or less, set it to 0
sIEVer = "0.0.0.0"
End If
On Error Goto 0
aIEVer = Split(sIEVer, ".")
SetLocale "en-us" ' Do not remove
iIEVersion = CDbl(aIEVer(0) & "." & aIEVer(1))
iIEBuildVersion = CDbl(aIEVer(2) & "." & aIEVer(3))
If iIEVersion = 5.0 Then
Select Case iIEBuildVersion
Case 2919.6307, 2920.0000
GetIEExactVersion = "IE5.01"
Case 3103.1000, 3105.0106
GetIEExactVersion = "IE5.01 SP1"
Case 3314.2101, 3315.1000
GetIEExactVersion = "IE5.01 SP2"
Case 3502.1000
GetIEExactVersion = "IE5.01 SP3"
Case 3700.1000
GetIEExactVersion = "IE5.01 SP4"
Case Else
GetIEExactVersion = sUnknownText
End Select
Elseif iIEVersion = 5.5 Then
Select Case iIEBuildVersion
Case 4134.0100, 4134.0600
GetIEExactVersion = "IE5.5"
Case 4522.1800
GetIEExactVersion = "IE5.5 SP1"
Case 4807.2300
GetIEExactVersion = "IE5.5 SP2"
Case Else
GetIEExactVersion = sUnknownText
End Select
Elseif iIEVersion = 6.0 Then
Select Case iIEBuildVersion
Case 2600.0000
GetIEExactVersion = "IE6"
Case 2800.1106
GetIEExactVersion = "6 SP1"
Case 2900.2180
GetIEExactVersion = "6 SP2"
Case 3790.0000
GetIEExactVersion = "6 Windows Server 2003"
Case 3790.1830
GetIEExactVersion = "6 Windows Server 2003 SP1"
Case Else
GetIEExactVersion = sUnknownText
End Select
Else
GetIEExactVersion = sUnknownText
End If
End Function
'--------------------8<----------------------
--
torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
Administration scripting examples and an ONLINE version of
the 1328 page Scripting Guide:
http://www.microsoft.com/technet/scriptcenter/default.mspx